Libraries

A library is a file of reusable code. Scripts load as many libraries as they need, libraries can load other libraries, and libraries can be organised in folders.

library "smc/zones"
/// Price zones with mitigation tracking.
use "smc/structure" as st

pub DEFAULT_ATR = 14

pub struct Zone {
    top: float = na
    bottom: float = na
    bullish: bool = true
    fn mid(self) -> float { return (self.top + self.bottom) / 2 }
    fn mitigated(self) -> bool { return self.bullish ? close < self.bottom : close > self.top }
}

pub fn fvg(min_atr: float = 0.1) -> (bool, Zone) {
    a = ta.atr(DEFAULT_ATR)
    bull = low > high[2] and low - high[2] >= a * min_atr
    bear = high < low[2] and low[2] - high >= a * min_atr
    z = Zone(top = bull ? low : low[2], bottom = bull ? high[2] : high, bullish = bull)
    return (bull or bear, z)
}

Using libraries

analysis "Zones" { overlay = true }

use "smc/zones"                  // alias: zones (the last part of the name)
use "smc/structure" as st
use "viz/palette" as pal

(found, gap) = zones.fvg(0.2)
persist kept = list.create(zones.Zone)
if found { list.push(kept, gap) }
render.mark(found, shape = shape.square, at = anchor.below_bar, color = pal.ACCENT)

• use "name" lines come before the other statements.
• The alias defaults to the last segment of the name; as picks another one.
• Only pub declarations are visible: functions, structs, enums and constants.
• A library's types travel with it: list.create(zones.Zone), zones.Zone(top = 1), zones.Zone.factory(...).
• Up to 16 libraries per program, nested up to 4 levels; cycles are reported with the chain.

Where libraries come from

use "smc/zones" loads smc/zones.qs relative to a library folder. The file must start with library "smc/zones"; a different name is an error, so a moved file is noticed.

Bundled libraries